10 REM FUNKTIONEN =============C64
20 REM (P) COMMODORE DISC
30 REM ===========================
40 REM (C) BY MICHAEL GROBE   V3.5
50 REM
60 REM (V)    A. MITTELMEYER  V2.0
70 REM
80 REM C64
90 REM ==========================
91 SYS57812"SUPERGRAPHICS.MC",8,0:POKE780,0
92 POKE782,191:POKE781,254:SYS65493
100 PRINTCHR$(147);:GOTO419
110 PRINTCHR$(147):PRINT:PRINT
120 PRINTTAB(8)"FUNKTIONSGRAPHEN C64"
130 PRINTTAB(8)"--------------------"
140 PRINT:PRINT:PRINT
150 PRINTTAB(9)"VON MICHAEL GROBE "
160 PRINT"----------------------------------------":PRINT
170 PRINT"GENAUIGKEIT"SPC(29)"(0.1 ODER 0.01 ODER 0.001):";:INPUTK
180 IFK<>0.1ANDK<>0.01ANDK<>0.001THEN170
190 PRINT"START X"SPC(2)"(-16 BIS 16)"SPC(5)":";:INPUTXS:IFXS<-16ORXS>16THEN190
200 PRINT"ZIEL"SPC(2)"X"SPC(2)"(-16 BIS 16)"SPC(5)":";:INPUTZZ:IFZZ<-16ORZZ>16THEN200
210 IFZZ<XSTHENPRINT"ZIEL X MUSS GROESSER SEIN ALS START X !":GOTO200
220 PRINT"LOESCHEN (0=N 1=J)"SPC(8)":";:INPUTL:IFL<>1ANDL<>0THENGOTO220
230 X=XS:Y=0:IFL=1THENSYS50941
240 SYS50906,1,0:SYS51090
250 SYS49415,0,100,319,100
260 SYS49415,160,0,160,199
270 FORI=1TO20
280 SYS49415,159,200-10*I,161,200-10*I:NEXT
290 FORI=0TO31
300 SYS49415,10*I,99,10*I,101:NEXT
310 IFX>ZZTHEN410
320 REM =========================
330 Y=5*SIN(X/5)
340 REM =========================
350 A=160+(X*10)
360 B=100-(Y*10)
370 IFB<0ORB>255THEN390
380 SYS49264,A,B
390 X=X+K
400 GOTO310
410 SYS50088,1,1,"OK":GOSUB421:SYS50088,1,1,"  ":SYS51115
419 PRINTCHR$(147):PRINT:PRINT"RUN110":POKE198,2:POKE631,19
420 POKE632,17:PRINTCHR$(19);:LIST330:END
421 GETM$:IFM$=""THEN421
422 RETURN
430 REM =========================
440 REM  P R O G R A M M E N D E
450 REM =========================